TCS3200 Color Sensor Tutorial | Arduino | TCS230

In this tutorial, we will see how to use TCS3200/TCS230 color sensor with Arduino. This color sensor is used in wide range of applications like conveyors, food processing units, paint mixing applications, Vending machines and many more. So let’s see how it works and how to use it with Arduino.

At the center of the sensor, you can able to see the TCS3200 Chip. It consists of 8×8 arrays of photodiodes (Total 64 photodiodes). There is a current to frequency converter that converts the sensed current from photodiode into a square wave frequency. This frequency determines the color of the object in front of TCS3200.

There are 4 White LEDs around the TCS3200 chip is to apply a plain white color on the object and the reflected amount of color is detected by photodiodes.

Block Diagram

As you can see the block diagram of TCS3200 color sensor, there are 64 diodes of each colors Red, Blue, Clear and Green. These can be configured by S2 and S3 Pin of this module to read a specific color. In the current to frequency converter, the output from sensor is converted into frequency. Here, the S0 and S1 pins are used to scale the frequency according to different microcontroller speeds. The table is given below to configure these modes,

Frequency Scaling Configuration

Type of Photodiode (RGB)

We will read all the values by setting the S2 and S3 Pins one by one and store in the variable. By using this variable you can print it on the serial monitor or perform some actions like turning a servo for color sorting machines.

Circuit Diagram:

In our example, we will use an RGB LED to lit up the color which is detected by the Color Sensor. This code will detect only the three primary colors RED, GREEN and BLUE. If you want to detect a specific color you can extend it by the color values.

Note: Here, we are using Common Anode RGB LED so I have connected 5V at the Common terminal. If your RGB LED is common Cathode you should connect it to Ground.

RGB LED Pinout:

Code:

/*

// TCS230 & 3200 color recognition sensor

// Sensor connection pins to Arduino are shown in comments

Color Sensor      Arduino

-----------      --------

 VCC               5V

 GND               GND

 s0                8

 s1                9

 s2                12

 s3                11

 OUT               10

 OE                GND

*/

const int s0 = 8; 

const int s1 = 9; 

const int s2 = 12; 

const int s3 = 11; 

const int out = 10;


// LED pins connected to Arduino

int redLed = 2; 

int greenLed = 3; 

int blueLed = 4;

// Variables 

int red = 0; 

int green = 0; 

int blue = 0; 

void setup()  

{ 

  Serial.begin(9600);

  pinMode(s0, OUTPUT); 

  pinMode(s1, OUTPUT); 

  pinMode(s2, OUTPUT); 

  pinMode(s3, OUTPUT); 

  pinMode(out, INPUT); 

  pinMode(redLed, OUTPUT); 

  pinMode(greenLed, OUTPUT); 

  pinMode(blueLed, OUTPUT);


  //Setting frequncy to 100%

  digitalWrite(s0, HIGH); 

  digitalWrite(s1, HIGH); 

} 


void loop()

{ 

  color();

  Serial.print("R Intensity:"); 

  Serial.print(red, DEC); 

  Serial.print(" G Intensity: "); 

  Serial.print(green, DEC); 

  Serial.print(" B Intensity : "); 

  Serial.print(blue, DEC); 

  //Serial.println(); 


/* This is for common Anode LEDs, Change HIGH and LOW to opposite for Common Cathode*/

  if (red < blue && red < green && red < 20)

  { 

   Serial.println(" - (Red Color)"); 

   digitalWrite(redLed, LOW); // Turn RED LED ON

   digitalWrite(greenLed, HIGH); 

   digitalWrite(blueLed, HIGH); 

  } 



  else if (blue < red && blue < green)  

  { 

   Serial.println(" - (Blue Color)"); 

   digitalWrite(redLed, HIGH); 

   digitalWrite(greenLed, HIGH); 

   digitalWrite(blueLed, LOW); // Turn BLUE LED ON 

  } 



  else if (green < red && green < blue) 

  { 

   Serial.println(" - (Green Color)"); 

   digitalWrite(redLed, HIGH); 

   digitalWrite(greenLed, LOW); // Turn GREEN LED ON

   digitalWrite(blueLed, HIGH); 

  } 

  else{

  Serial.println(); 

  }

  delay(300);  

  digitalWrite(redLed, HIGH); 

  digitalWrite(greenLed, HIGH); 

  digitalWrite(blueLed, HIGH); 

 } 


/* Read and Store values in red, green and blue variables */   

void color() 

{  

  //s2 and s3 to LOW for reading RED Values

  digitalWrite(s2, LOW); 

  digitalWrite(s3, LOW); 

  red = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH);



  //s3 to HIGH (Already s2 in LOW) for BLUE values 

  digitalWrite(s3, HIGH); 

  blue = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH);



  //s2 to HIGH (Already s3 HIGH) for GREEN

  digitalWrite(s2, HIGH); 

  green = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH); 

}

Make sure the correct Board and COM Port is selected then upload the code. Open serial monitor, now place any Red/Green/Blue colored object in front of Color sensor. It will show the color value in decimal and also the color of the object. Similarly, you can notice the RGB LED will light according to the Object color.